Како се користи функција Екцел ВЛООКУП -

Резиме

ВЛООКУП је Екцел функција за тражење података у табели вертикално организованој. ВЛООКУП подржава приближно и тачно подударање, као и џокер знакове (*?) За делимична подударања. Вредности претраживања морају се појавити у првој колони табеле прослеђене у ВЛООКУП.

Сврха

Потражите вредност у табели подударањем у првој колони

Повратна вредност

Подударна вредност из табеле.

Синтакса

= ВЛООКУП (вредност, табела, цол_индек, (ранге_лоокуп))

Аргументи

вредност - вредност коју треба тражити у првом ступцу табеле.
табела - табела из које се преузима вредност.
цол_индек - Колона у табели из које се преузима вредност.
ранге_лоокуп - (опционално) ТРУЕ = приближно подударање (подразумевано). ФАЛСЕ = тачно подударање.

Верзија

Екцел 2003

Напомене о употреби

ВЛООКУП је Екцел функција за добијање података из табеле вертикално организоване. Вредности претраживања морају се појавити у првој колони табеле прослеђене у ВЛООКУП. ВЛООКУП подржава приближно и тачно подударање, као и џокер знакове (*?) За делимична подударања.

В је за вертикалну

Сврха ВЛООКУП-а је да добије информације из табеле организоване овако:

Користећи број поруџбине у колони Б као вредност претраживања, ВЛООКУП може добити ИД купца, износ, име и стање за било коју поруџбину. На пример, да бисте добили име купца за поруџбину 1004, формула је:

=VLOOKUP(1004,B5:F9,4,FALSE) // returns "Sue Martin"

За хоризонталне податке можете да користите ХЛООКУП, ИНДЕКС и МАТЦХ или КСЛООКУП.

ВЛООКУП се заснива на бројевима колона

Када користите ВЛООКУП, замислите да су све колоне у табели нумерисане, почев од леве стране. Да бисте добили вредност из одређене колоне, наведите одговарајући број као „индекс колоне“. На пример, индекс колоне за преузимање имена испод је 2:

Презиме и адреса е-поште могу се преузети помоћу колона 3 и 4:

=VLOOKUP(H3,B4:E13,2,FALSE) // first name =VLOOKUP(H3,B4:E13,3,FALSE) // last name =VLOOKUP(H3,B4:E13,4,FALSE) // email address

ВЛООКУП изгледа само исправно

ВЛООКУП може гледати само удесно. Подаци које желите да преузмете (вредности резултата) могу се појавити у било којој колони десно од вредности претраживања:

Ако требате потражити вредности лево, погледајте ИНДЕКС и УТАКМИЦА или КСЛООКУП.

Тачно и приближно подударање

ВЛООКУП има два начина подударања, тачно и приближно. Име аргумента који контролише подударање је " ранге_лоокуп ". Ово је збуњујуће име, јер изгледа да има неке везе са опсезима ћелија попут А1: А10. Заправо, реч „опсег“ у овом случају се односи на „опсег вредности“ - када је распон_истраживања ИСТИНА, ВЛООКУП ће одговарати опсегу вредности, а не тачној вредности. Добар пример за то је коришћење ВЛООКУП-а за израчунавање оцена.

Важно је схватити да је ранге_лоокуп подразумевано подешен на ТРУЕ, што значи да ће ВЛООКУП подразумевано користити приближно подударање, што може бити опасно. Подесите ранге_лоокуп на ФАЛСЕ да бисте наметнули тачно подударање:

=VLOOKUP(value, table, col_index) // approximate match (default) =VLOOKUP(value, table, col_index, TRUE) // approximate match =VLOOKUP(value, table, col_index, FALSE) // exact match

Напомена: Такође можете да наведете нулу (0) уместо ФАЛСЕ за тачно подударање.

Тачан меч

У већини случајева вероватно ћете желети да користите ВЛООКУП у режиму тачног подударања. То има смисла када имате јединствени кључ који ћете користити као вредност претраживања, на пример, наслов филма у овим подацима:

Формула у Х6 за проналажење године , заснована на тачном подударању наслова филма, је:

=VLOOKUP(H4,B5:E9,2,FALSE) // FALSE = exact match

Приближно подударање

In cases when you want the best match , not necessarily an exact match , you'll want to use approximate mode. For example, below we want to look up a commission rate in the table G5:H10. The lookup values come from column C. In this example, we need to use VLOOKUP in approximate match mode, because in most cases an exact match will never be found. The VLOOKUP formula in D5 is configured to perform an approximate match by setting the last argument to TRUE:

=VLOOKUP(C5,$G$5:$H$10,2,TRUE) // TRUE = approximate match

VLOOKUP will scan values in column G for the lookup value. If an exact match is found, VLOOKUP will use it. If not, VLOOKUP will "step back" and match the previous row.

Note: data must be sorted in ascending order by lookup value when you use approximate match mode with VLOOKUP.

First match

In the case of duplicate values, VLOOKUP will find the first match when the match mode is exact. In screen below, VLOOKUP is configured to find the price for the color "Green". There are three entries with the color Green, and VLOOKUP returns the price for the first entry, $17. The formula in cell F5 is:

=VLOOKUP(E5,B5:C11,2,FALSE) // returns 17

Wildcard match

The VLOOKUP function supports wildcards, which makes it possible to perform a partial match on a lookup value. For instance, you can use VLOOKUP to retrieve values from a table after typing in only part of a lookup value. To use wildcards with VLOOKUP, you must specify exact match mode by providing FALSE or 0 for the last argument, range_lookup . The formula in H7 retrieves the first name, "Michael", after typing "Aya" into cell H4:

=VLOOKUP($H$4&"*",$B$5:$E$104,2,FALSE)

Read a more detailed explanation here.

Two-way lookup

Inside the VLOOKUP function, the column index argument is normally hard-coded as a static number. However, you can also create a dynamic column index by using the MATCH function to locate the right column. This technique allows you to create a dynamic two-way lookup, matching on both rows and columns. In the screen below, VLOOKUP is configured to perform a lookup based on Name and Month. The formula in H6 is:

=VLOOKUP(H4,B5:E13,MATCH(H5,B4:E4,0),0)

For more details, see this example.

Note: In general, INDEX and MATCH is a more flexible way to perform two-way lookups.

Multiple criteria

The VLOOKUP function does not handle multiple criteria natively. However, you can use a helper column to join multiple fields together, and use these fields like multiple criteria inside VLOOKUP. In the example below, Column B is a helper column that concatenates first and last names together with this formula:

=C5&D5 // helper column

VLOOKUP is configured to do the the same thing to create a lookup value. The formula in H6 is:

=VLOOKUP(H4&H5,B5:E13,4,0)

For details, see this example.

Note: INDEX and MATCH and XLOOKUP are more robust ways to handle lookups based on multiple criteria.

VLOOKUP and #N/A errors

If you use VLOOKUP you will inevitably run into the #N/A error. The #N/A error just means "not found". For example, in the screen below, the lookup value "Toy Story 2" does not exist in the lookup table, and all three VLOOKUP formulas return #N/A:

One way to "trap" the NA error is to use the IFNA function like this:

The formula in H6 is:

=IFNA(VLOOKUP(H4,B5:E9,2,FALSE),"Not found")

The message can be customized as desired. To return nothing (i.e. to display a blank result) when VLOOKUP returns #N/A you can use an empty string like this:

=IFNA(VLOOKUP(H4,B5:E9,2,FALSE),"") // no message

The #N/A error is useful because it tells you something is wrong. In practice, there are many reasons why you might see this error, including:

The lookup value does not exist in the table
The lookup value is misspelled, or contains extra space
Match mode is exact, but should be approximate
The table range is not entered correctly
You are copying VLOOKUP, and the table reference is not locked

More about VLOOKUP

More VLOOKUP examples
VLOOKUP videos
23 tips for using VLOOKUP

Other notes

Range_lookup controls whether value needs to match exactly or not. The default is TRUE = allow non-exact match.
Set range_lookup to FALSE to require an exact match and TRUE to allow a non-exact match .
If range_lookup is TRUE (the default setting), a non-exact match will cause the VLOOKUP function to match the nearest value in the table that is still less than value .
When range_lookup is omitted, the VLOOKUP function will allow a non-exact match, but it will use an exact match if one exists.
If range_lookup is TRUE (the default setting) make sure that lookup values in the first row of the table are sorted in ascending order. Otherwise, VLOOKUP may return an incorrect or unexpected value.
If range_lookup is FALSE (require exact match), values in the first column of table do not need to be sorted.